home *** CD-ROM | disk | FTP | other *** search
/ Shareware Games Galore! / Shareware Games Galore!.iso / arcade / gameser5 / golf.bas (.txt) < prev    next >
Encoding:
GW-BASIC  |  1982-03-04  |  6.1 KB  |  265 lines
  1. 100  CLS
  2. 110  A$=STRING$(80,205)
  3. 120  PRINT A$
  4. 130  PRINT TAB(36)"GOLF 2006"
  5. 140  COLOR 23,0,0
  6. 150  PRINT :PRINT :PRINT TAB(39)"IPCO"
  7. 160  COLOR 7,0,0
  8. 170  PRINT :PRINT :PRINT TAB(25)"PERSONAL COMPUTER OWNERS GROUP"
  9. 180  PRINT :PRINT :PRINT TAB(19)"p.o. box 10426, pittsburgh, pennsylvania 15234"
  10. 190  PRINT A$
  11. 200  PRINT :PRINT :PRINT :PRINT :PRINT
  12. 210  PRINT TAB(28)"PRESS ANY KEY TO CONTINUE"
  13. 220  A$=INKEY$:IF A$="" THEN 220
  14. 230  CLS
  15. 240  REM CONVERTED BY STEVE ESTLE
  16. 250  CLS
  17. 260  RANDOMIZE
  18. 270  DIM A$(25)
  19. 280  A$(1)="1ST TEE"
  20. 290  A$(2)="2ND TEE"
  21. 300  A$(3)="3RD TEE"
  22. 310  A$(4)="4TH TEE"
  23. 320  A$(5)="5TH TEE"
  24. 330  A$(6)="6TH TEE"
  25. 340  A$(7)="7TH TEE"
  26. 350  A$(8)="8TH TEE"
  27. 360  A$(9)="9TH TEE"
  28. 370  A$(10)="10TH TEE"
  29. 380  A$(11)="11TH TEE"
  30. 390  A$(12)="12TH TEE"
  31. 400  A$(13)="13TH TEE"
  32. 410  A$(14)="14TH TEE"
  33. 420  A$(15)="15TH TEE"
  34. 430  A$(16)="16TH TEE"
  35. 440  A$(17)="17TH TEE"
  36. 450  A$(18)="18TH TEE"
  37. 460  PRINT
  38. 470  PRINT
  39. 480  PRINT
  40. 490  INPUT "ARE YOU A NEW MEMBER OF THE CLUB?  ENTER Y OR N";X$
  41. 500  CLS
  42. 510  IF X$="Y" THEN 550
  43. 520  IF X$="N" THEN 790
  44. 530  PRINT "I CAN SEE YOU HAVE ALREADY SPENT CONSIDERABLE TIME AT THE 19THHOLE TRY ANSWERING AGAIN."
  45. 540  GOTO 490
  46. 550  PRINT :PRINT :PRINT :PRINT
  47. 560  PRINT "             YOU ARE ABOUT TO PLAY A ROUND OF GOLF                                           AT THE NEW AND EXCITING ESSICK COUNTRY                                          CLUB."
  48. 570  PRINT
  49. 580  PRINT TAB(18)"********** THESE ARE YOUR CLUBS **********"
  50. 590  PRINT
  51. 600  PRINT
  52. 610  PRINT TAB(26)"  4 WOODS NUMBERED 1 THRU 4"
  53. 620  PRINT
  54. 630  PRINT TAB(26)"  8 (EIGHT) IRONS  2 THRU 9"
  55. 640  PRINT
  56. 650  PRINT TAB(26)"  A PUTTER AND A WEDGE"
  57. 660  PRINT
  58. 670  PRINT
  59. 680  INPUT "PRESS ENTER FOR INSTRUCTIONS ";X0$
  60. 690  CLS
  61. 700  PRINT
  62. 710  PRINT
  63. 720  PRINT
  64. 730  PRINT "A PUTTER CAN BE USED ONLY ON THE GREEN.  YOU PUTT BY INPUTTING A NUMBER FROM 1  TO 10. THE DISTANCE AND ACCURACY OF YOUR PUTT ARE CONTROLLED BY THE MAGNITUDE "
  65. 740  PRINT "OF YOUR INPUT.  A 1 WILL TAP THE BALL ACCURATELY, A TEN WILL DRIVE IT APPROX    100 FT WITH QUESTIONABLE ACCURACY."
  66. 750  PRINT
  67. 760  PRINT TAB(26)"PRESS ENTER TO CONTINUE.."
  68. 770  INPUT I9$
  69. 780  CLS
  70. 790  S=S+1
  71. 800  IF S<>19 THEN 830
  72. 810  K1=2
  73. 820  GOTO 2600
  74. 830  IF S<>10 THEN 930
  75. 840  K1=1
  76. 850  PRINT
  77. 860  PRINT
  78. 870  PRINT "DO YOU WANT TO PLAY ANOTHER NINE HOLES,  ";
  79. 880  INPUT "YES/NO ";X2$
  80. 890  IF X2$="Y" THEN 930
  81. 900  IF X2$="N" THEN 2600
  82. 910  PRINT :PRINT :PRINT "IF YOU PLAY LIKE YOU TYPE YOU WILL NEVER MAKE IT!!!"
  83. 920  GOTO 870
  84. 930  PRINT
  85. 940  PRINT
  86. 950  READ Y
  87. 960  Y1=Y
  88. 970  READ D
  89. 980  PRINT "YOU ARE ON THE ";A$(S);"..."
  90. 990  PRINT "IT IS ";Y;" YARDS LONG, PAR ";D
  91. 1000  C=0
  92. 1010  K=0
  93. 1020  PRINT
  94. 1030  IF INT(Y)=0 THEN 2150
  95. 1040  C=C+1
  96. 1050  IF S+C<3 THEN 1080
  97. 1060  PRINT :PRINT :PRINT "WEDGE, IRON OR WOOD";
  98. 1070  GOTO 1090
  99. 1080  PRINT "TELL ME WHICH TYPE OF CLUB TO USE, A WEDGE AN IRON OR A WOOD.  FROM NOW ON I    WILL JUST ASK WEDGE, IRON OR WOOD."
  100. 1090  INPUT Z$
  101. 1100  IF Z$="WOOD" THEN 1380
  102. 1110  IF Z$="WEDGE" THEN 1150
  103. 1120  IF Z$="IRON" THEN 1210
  104. 1130  PRINT "YOU CAN ONLY CHOOSE A WEDGE, IRON OR WOOD."
  105. 1140  GOTO 1090
  106. 1150  IF Y<(18*RND+73) THEN 1180
  107. 1160  PRINT "  HEY... YOU CAN'T USE A WEDGE AT THIS DISTANCE...."
  108. 1170  GOTO 1060
  109. 1180  IF INT(15*RND)=13 THEN 2530
  110. 1190  Y=Y-(INT(75*RND+50))
  111. 1200  GOTO 2070
  112. 1210  PRINT "WHAT NUMBER IRON ";
  113. 1220  INPUT A
  114. 1230  IF A<2 THEN 1260
  115. 1240  IF A>9 THEN 1260
  116. 1250  GOTO 1280
  117. 1260  PRINT "YOUR IRONS ARE NUMBERED 2 THRU 9, RETYPE..."
  118. 1270  GOTO 1220
  119. 1280  IF K=0 THEN 1310
  120. 1290  IF INT(5*RND)=3 THEN 2070
  121. 1300  GOTO 2020
  122. 1310  M=INT(35*RND+200)
  123. 1320  X=INT(M-14.4*A-(7*RND+38))
  124. 1330  Y=Y-X
  125. 1340  IF M/27=INT(M/27) THEN 1950
  126. 1350  IF M/8=INT(M/8) THEN 1850
  127. 1360  IF M/69=INT(M/69) THEN 2530
  128. 1370  GOTO 1700
  129. 1380  PRINT "WHAT NUMBER WOOD";
  130. 1390  INPUT A
  131. 1400  IF A<1 THEN 1430
  132. 1410  IF A>4 THEN 1430
  133. 1420  GOTO 1450
  134. 1430  PRINT "YOUR WOODS ARE NUMBERED 1-4, RETYPE...";
  135. 1440  GOTO 1390
  136. 1450  IF K=0 THEN 1480
  137. 1460  IF INT(7*RND)=3 THEN 2070
  138. 1470  GOTO 2020
  139. 1480  X=INT(RND*250)
  140. 1490  IF A<>1 THEN 1520
  141. 1500  IF X<220 THEN 1480
  142. 1510  GOTO 1620
  143. 1520  IF A<>2 THEN 1560
  144. 1530  IF X<210 THEN 1480
  145. 1540  IF X>230 THEN 1480
  146. 1550  GOTO 1620
  147. 1560  IF A<>3 THEN 1600
  148. 1570  IF X<200 THEN 1480
  149. 1580  IF X>220 THEN 1480
  150. 1590  GOTO 1620
  151. 1600  IF X<190 THEN 1480
  152. 1610  IF X>210 THEN 1480
  153. 1620  Y=Y-X
  154. 1630  FOR I=1 TO (4-A+C^2)
  155. 1640  V=INT(30*RND)
  156. 1650  IF X/11=INT(X/11) THEN 1770
  157. 1660  IF X/5=INT(X/5) THEN 1900
  158. 1670  IF X/28=INT(X/28) THEN 1800
  159. 1680  IF X/27=INT(X/27) THEN 1950
  160. 1690  NEXT I
  161. 1700  IF Y>27 THEN 1750
  162. 1710  IF Y<-23 THEN 1990
  163. 1720  IF ABS(Y)<5 THEN 1880
  164. 1730  IF (3.3*RND)=2 THEN 1840
  165. 1740  GOTO 2070
  166. 1750  PRINT "YOU HIT IT ";X;" YARDS. YOU ARE ";Y;" YARDS AWAY."
  167. 1760  GOTO 1020
  168. 1770  IF Y<25 THEN 1850
  169. 1780  PRINT "YOU ARE IN THE LEFT ROUGH ";Y;" YARDS AWAY."
  170. 1790  GOTO 1020
  171. 1800  PRINT "YOU SLICED THE BALL INTO A POND.  LOSE TWO STROKES AND REPLAY.."
  172. 1810  C=C+1
  173. 1820  Y=Y1
  174. 1830  GOTO 1020
  175. 1840  Y=ABS(Y)
  176. 1850  Y=30*RND+15
  177. 1860  PRINT "YOU'RE IN A TRAP NEAR THE GREEN."
  178. 1870  GOTO 1020
  179. 1880  PRINT "YOU S U N K THE SHOT......."
  180. 1890  GOTO 2540
  181. 1900  IF V/6=A THEN 1950
  182. 1910  IF Y-20<X-(A*V) THEN 1700
  183. 1920  PRINT "YOU`RE IN THE RIGHT ROUGH ";Y+25;" YARDS AWAY..."
  184. 1930  Y=Y-25
  185. 1940  GOTO 1020
  186. 1950  PRINT "THE BALL IS LOST IN THE WOODS.  REPLAY....TWO STROKE PENALTY.."
  187. 1960  C=C+1
  188. 1970  Y=Y1
  189. 1980  GOTO 1020
  190. 1990  Y=ABS(Y)
  191. 2000  PRINT "YOU OVERSHOT THE GREEN BY ";Y;" YARDS..."
  192. 2010  GOTO 1020
  193. 2020  IF INT(2*RND)=1 THEN 2050
  194. 2030  PRINT "THE IDEA IS TO HIT THE BALL NOT THE SAND.."
  195. 2040  GOTO 1020
  196. 2050  PRINT "YOU TOPPED IT NO GAIN.."
  197. 2060  GOTO 1020
  198. 2070  IF INT(4*RND)<>3 THEN 2100
  199. 2080  F=INT(10*RND)
  200. 2090  GOTO 2140
  201. 2100  IF INT(7*RND)<>7 THEN 2130
  202. 2110  F=INT(50*RND+50)
  203. 2120  GOTO 2140
  204. 2130  F=INT(50*RND+10)
  205. 2140  IF INT(F)=0 THEN 2540
  206. 2150  IF F<>1 THEN 2180
  207. 2160  PRINT "YOU ARE ON THE GREEN 1 FT FROM THE PIN.. LUCK SHOT...."
  208. 2170  GOTO 2200
  209. 2180  PRINT "YOU ARE ON THE GREEN,";F;"FEET FROM THE PIN..."
  210. 2190  PRINT
  211. 2200  PRINT
  212. 2210  C=C+1
  213. 2220  PRINT "WHAT IS YOUR PUTT";
  214. 2230  INPUT A
  215. 2240  IF A>10 THEN 2270
  216. 2250  IF A<1 THEN 2270
  217. 2260  GOTO 2290
  218. 2270  PRINT "CAN'T USE THAT...RETYPE."
  219. 2280  GOTO 2230
  220. 2290  K=F
  221. 2300  F=INT(F=(A^2+A-((0.5*A^2-A+1)*RND)))
  222. 2310  IF ABS(F)>(RND+1.5) THEN 2390
  223. 2320  IF K>5 THEN 2480
  224. 2330  IF INT(10*RND)=7 THEN 2360
  225. 2340  PRINT "THE TAP IS GOOD.."
  226. 2350  GOTO 2540
  227. 2360  PRINT "OH BOY, YOU JABBED THE PUTT";INT(9*RND+2);"INCHES FROM THE CUP.."
  228. 2370  F=1
  229. 2380  GOTO 2200
  230. 2390  IF F=0 THEN 2480
  231. 2400  IF F>0 THEN 2430
  232. 2410  F=ABS(F)
  233. 2420  PRINT "YOU OVERSHOT THE BLOOMING CUP!!!"
  234. 2430  IF F<>1 THEN 2460
  235. 2440  PRINT "YOU ARE ONE FOOT FROM THE PIN..."
  236. 2450  GOTO 2390
  237. 2460  PRINT "YOU ARE NOW ";F;" FEET FROM THE PIN..."
  238. 2470  GOTO 2200
  239. 2480  IF K<>1 THEN 2510
  240. 2490  PRINT "YOU SUNK IT FROM ONE FOOT."
  241. 2500  GOTO 2540
  242. 2510  PRINT "YOU SUNK IT FROM ";K;" FEET.."
  243. 2520  GOTO 2540
  244. 2530  PRINT "YOU    S U N K    IT!!!!!!"
  245. 2540  PRINT
  246. 2550  IF C<>1 THEN 2570
  247. 2560  PRINT "************HOLE   IN   ONE**************"
  248. 2570  E=E+C
  249. 2580  PRINT "YOU HAVE HAD ";C;" STROKES ON HOLE NUMBER ";S;"."
  250. 2590  GOTO 790
  251. 2600  PRINT "AFTER";(K1*9);"HOLES YOU HAVE HAD";E;" STROKES..."
  252. 2610  IF K1*36-E<0 THEN 2700
  253. 2620  IF (K1*36-E)<>0 THEN 2650
  254. 2630  PRINT "NICE GAME....... YOU SHOT PAR!!!!"
  255. 2640  GOTO 2730
  256. 2650  PRINT "THE PAR IS";(K1*36);".  YOU ARE";(K1*36-E);"UNDER PAR."
  257. 2660  PRINT
  258. 2670  PRINT TAB(28)"CONGRATULATIONS!!!!!!"
  259. 2680  PRINT :PRINT :PRINT TAB(12)"YOU PLAYED A GREAT GAME AT THE ESSICK COUNTRY CLUB !!!!"
  260. 2690  GOTO 2730
  261. 2700  PRINT "THE PAR IS";(K1*36);".  YOU ARE";(E-K1*36);"OVER PAR."
  262. 2710  DATA 374,4,434,4,210,3,376,4,205,3,440,4,422,4,510,5,595,5
  263. 2720  DATA 510,5,434,4,210,3,312,4,428,4,440,4,205,3,515,5,318,4
  264. 2730  END
  265.